自定义函数: textBar ( value ; barUnitValue ; maxValue ; finishedSymbol ; finishedSymbolColor ; unfinishedSymbol ; unfinishedSymbolColor ; symbolSize ; hideDetail ; detailText ; detailSize )

2020年6月15日 • 原创 • 进度条

函数功能描述

来源:

作者: Cliff Zhou

作者原述:

猫壹佰描述:

生成一个简易文本进度条

参数说明:

value: 当前进度值

barUnitValue: 代表进度进程的百分比单位, 比如填写20代表20%作为一个进度单位, 填写1则代表1%作为一个进度单位,允许值为 0.5 / 1 / 2 / 4 / 5 / 10 / 20 / 25, 其他值会报错

maxValue: 限定最高值, 满分值, 默认为100

finishedSymbol: 已完成符号, 默认为"█"

finishedSymbolColor: 已完成符号RGB颜色, 填写格式RGB(255;0;0), 默认为黑色

unfinishedSymbol: 未完成符号, 默认为"█"

unfinishedSymbolColor: 未完成符号RGB颜色, 填写格式RGB(255;0;0), 默认为灰色

symbolSize: 符号字体大小, 默认为12号字体

hideDetail: 是否隐藏详细描述, 值为1时隐藏, 0为显示, 默认为显示

detailText: 详细描述文本

detailSize: 详细描述文本大小, 默认为12号字体

测试文档下载:

调用范例

textBar(644 ; 20 ;1000 ; "★"; RGB(0;0;255) ; "☆" ; RGB(180;180;255); 24 ; 0; "" ; "" )

textBar(644 ; 10 ;1000 ; "◼︎"; ""; "◻︎" ; ""; 24 ; 0; "¶ finished" ; "" )

返回结果

★★★☆☆ (644/1000)

◼︎◼︎◼︎◼︎◼︎◼︎◻︎◻︎◻︎◻︎
finished (644/1000)

函数内容

/*

一个简易的文本进度条自定义函数
textBar ( value ; barUnitValue ; maxValue ; finishedSymbol ; finishedSymbolColor ; unfinishedSymbol ; unfinishedSymbolColor ; symbolSize ; hideDetail ; detailText ; detailSize )

作者: Cliff Zhou
作者网站: https://mao100.com
QQ: 228740074

参数说明:
value:                            当前进度值
barUnitValue:                代表进度进程的百分比单位, 比如填写20代表20%作为一个进度单位, 填写1则代表1%作为一个进度单位,允许值为  0.5 / 1 / 2 / 4 / 5 / 10 / 20 / 25, 其他值会报错
maxValue:                     限定最高值, 满分值, 默认为100
finishedSymbol:             已完成符号, 默认为"█"
finishedSymbolColor:     已完成符号RGB颜色, 填写格式RGB(255;0;0), 默认为黑色
unfinishedSymbol:          未完成符号, 默认为"█"
unfinishedSymbolColor: 未完成符号RGB颜色, 填写格式RGB(255;0;0), 默认为灰色
symbolSize:                    符号字体大小, 默认为12号字体
hideDetail:                      是否隐藏详细描述, 值为1时隐藏, 0为显示, 默认为显示
detailText:                      详细描述文本
detailSize:                      详细描述文本大小, 默认为12号字体

*/

Let ( [ 
         maxValue  = Abs( GetAsNumber( maxValue ) );
         maxValue  = Case( IsEmpty( maxValue ); 100; maxValue );
         ~barCount = Floor(Floor( (value/maxValue) *100) / barUnitValue);
         ~barMaxCount = Int( 100 / barUnitValue );
         x = 10^~barCount - 1;
         y = 10^( ~barMaxCount - ~barCount ) - 1;
         finishedSymbol = Case( IsEmpty( finishedSymbol ); "█"; finishedSymbol );
         finishedSymbolColor = Case( IsEmpty( finishedSymbolColor ); RGB(0;0;0); finishedSymbolColor );
         unfinishedSymbol = Case( IsEmpty( unfinishedSymbol ); "█"; unfinishedSymbol );
         unfinishedSymbolColor = Case( IsEmpty( unfinishedSymbolColor ); RGB(220;220;220); unfinishedSymbolColor );
         symbolSize = Case( GetAsNumber(symbolSize ) = 0; 12; Abs( symbolSize ) );
         detailSize = Case( GetAsNumber( detailSize ) = 0; 12; Abs( detailSize ) )
        ];

       
       Case( 
               value > maxValue or value < 0;
               "wrong value, value is allowed between 0 and " & maxValue;

               GetValue(FilterValues ( ".5¶1¶2¶4¶5¶10¶20¶25¶" ; barUnitValue);1) ≠ barUnitValue or barUnitValue ≤ 0;
               "barUnitValue is wrong, only 0.5 or 1 or 2 or 4 or 5 or 10 or 20 or 25 allowed";

               TextSize( TextColor(Substitute( x; ["9"; finishedSymbol]; ["0"; ""] ); finishedSymbolColor ) & TextColor( Substitute( y; ["9"; unfinishedSymbol]; ["0"; ""]); unfinishedSymbolColor ) ;
       symbolSize ) & Case( hideDetail; "";  TextSize(detailText & " (" & value & "/" & maxValue & ")"; detailSize ) )
       )

)

当前页面使用FileMaker生成发布, 更新于2021年3月15日0时45分44秒

← 较旧的文章较新的文章 →